サブプロの作り方
コーディングする
ポイントはソース内の太文字を参照。このサブプログラムは県コードから県名を取得する機能を実現する予定。
ソースの保管場所と名前は以下の通り。
→C:/cygwin/home/各ユーザID/cobol/GETPRFCT.COB
IDENTIFICATION DIVISION.
PROGRAM-ID. GETPRFCT.
*------------------------------------------------------------
* 県名取得プログラム（サブプロの特徴はコメント参照）
*------------------------------------------------------------
AUTHOR. JIRO SUZUKI.
DATA DIVISION.
WORKING-STORAGE SECTION.
COPY PRFCTTBL.
01 CNS-AREA.
03 CNS-RTNCD.
05 CNS-RTNCD-NORMAL PIC X(02) VALUE "00".
05 CNS-RTNCD-UNMATCH PIC X(02) VALUE "04".
05 CNS-RTNCD-NOENTRY PIC X(02) VALUE "99".
03 CNS-NUMBER-OF-PREFECT PIC 9(02) COMP-3 VALUE 47.
03 CNS-MATCH PIC 9(01) COMP-3 VALUE 1.
01 SW-AREA.
03 SW-MATCH PIC 9(01) COMP-3.
01 WORK-AREA.
03 IDX PIC 9(02) COMP-3.
LINKAGE SECTION. *> このSECTIONにｲﾝﾀｰﾌｪｰｽを
COPY IO-PREFECT. *> 指定すること(今回は左記のｺﾋﾟｰ句)
PROCEDURE DIVISION USING IO-PREFECT. *> ｲﾝﾀｰﾌｪｰｽの01ﾚﾍﾞﾙを指定
MAIN SECTION.
MOVE CNS-RTNCD-NORMAL TO RTNCD.
MOVE SPACE TO PREFECTNAMEKANA OF IO-PREFECT.
MOVE SPACE TO PREFECTNAMEKANJI OF IO-PREFECT.
*
IF PREFECTCD OF IO-PREFECT = SPACE
MOVE CNS-RTNCD-NOENTRY TO RTNCD *>入力エラー
END-IF.
*
IF RTNCD = CNS-RTNCD-NORMAL
MOVE 0 TO SW-MATCH
MOVE 1 TO IDX
PERFORM UNTIL IDX > CNS-NUMBER-OF-PREFECT
IF PREFECTCD OF IO-PREFECT =
PREFECTCD OF PRFCTTBL(IDX)
MOVE PREFECTNAMEKANA OF PRFCTTBL(IDX)
TO PREFECTNAMEKANA OF IO-PREFECT
MOVE PREFECTNAMEKANJI OF PRFCTTBL(IDX)
TO PREFECTNAMEKANJI OF IO-PREFECT
MOVE CNS-NUMBER-OF-PREFECT TO IDX
MOVE CNS-MATCH TO SW-MATCH
END-IF
ADD 1 TO IDX
END-PERFORM
END-IF.
*
IF SW-MATCH NOT = CNS-MATCH
MOVE CNS-RTNCD-UNMATCH TO RTNCD *>アンマッチエラー
END-IF.
*
GOBACK. *>最後はこれ(STOP RUNにしない)
コピー句を作成する
コピー句の作成場所と名前は以下の通り。→C:/cygwin/home/各ユーザID/copy/IO-PREFECT.COB
01 IO-PREFECT.
03 PREFECTCD PIC X(02).
03 RTNCD PIC X(02).
03 PREFECTNAMEKANA PIC X(10).
03 PREFECTNAMEKANJI PIC N(10).
03 PIC X(16).
県テーブルを作成する
コピー句の作成場所と名前は以下の通り。→C:/cygwin/home/各ユーザID/copy/PRFCTTBL.COB
01 PRFCTTBL. *>県テーブル
03 PRFCTTBL-VALUE.
05 PIC X(32) VALUE "01ﾎｯｶｲﾄﾞｳ 北海道 ".
05 PIC X(32) VALUE "02ｱｵﾓﾘｹﾝ 青森県 ".
05 PIC X(32) VALUE "03ｲﾜﾃｹﾝ 岩手県 ".
05 PIC X(32) VALUE "04ﾐﾔｷﾞｹﾝ 宮城県 ".
05 PIC X(32) VALUE "05ｱｷﾀｹﾝ 秋田県 ".
05 PIC X(32) VALUE "06ﾔﾏｶﾞﾀｹﾝ 山形県 ".
05 PIC X(32) VALUE "07ﾌｸｼﾏｹﾝ 福島県 ".
05 PIC X(32) VALUE "08ｲﾊﾞﾗｷｹﾝ 茨城県 ".
05 PIC X(32) VALUE "09ﾄﾁｷﾞｹﾝ 栃木県 ".
05 PIC X(32) VALUE "10ｸﾞﾝﾏｹﾝ 群馬県 ".
05 PIC X(32) VALUE "11ｻｲﾀﾏｹﾝ 埼玉県 ".
05 PIC X(32) VALUE "12ﾁﾊﾞｹﾝ 千葉県 ".
05 PIC X(32) VALUE "13ﾄｳｷｮｳﾄ 東京都 ".
05 PIC X(32) VALUE "14ｶﾅｶﾞﾜｹﾝ 神奈川県 ".
05 PIC X(32) VALUE "15ﾆｲｶﾞﾀｹﾝ 新潟県 ".
05 PIC X(32) VALUE "16ﾄﾔﾏｹﾝ 富山県 ".
05 PIC X(32) VALUE "17ｲｼｶﾜｹﾝ 石川県 ".
05 PIC X(32) VALUE "18ﾌｸｲｹﾝ 福井県 ".
05 PIC X(32) VALUE "19ﾔﾏﾅｼｹﾝ 山梨県 ".
05 PIC X(32) VALUE "20ﾅｶﾞﾉｹﾝ 長野県 ".
05 PIC X(32) VALUE "21ｷﾞﾌｹﾝ 岐阜県 ".
05 PIC X(32) VALUE "22ｼｽﾞｵｶｹﾝ 静岡県 ".
05 PIC X(32) VALUE "23ｱｲﾁｹﾝ 愛知県 ".
05 PIC X(32) VALUE "24ﾐｴｹﾝ 三重県 ".
05 PIC X(32) VALUE "25ｼｶﾞｹﾝ 滋賀県 ".
05 PIC X(32) VALUE "26ｷｮｳﾄﾌ 京都府 ".
05 PIC X(32) VALUE "27ｵｵｻｶﾌ 大阪府 ".
05 PIC X(32) VALUE "28ﾋｮｳｺﾞｹﾝ 兵庫県 ".
05 PIC X(32) VALUE "29ﾅﾗｹﾝ 奈良県 ".
05 PIC X(32) VALUE "30ﾜｶﾔﾏｹﾝ 和歌山県 ".
05 PIC X(32) VALUE "31ﾄｯﾄﾘｹﾝ 鳥取県 ".
05 PIC X(32) VALUE "32ｼﾏﾈｹﾝ 島根県 ".
05 PIC X(32) VALUE "33ｵｶﾔﾏｹﾝ 岡山県 ".
05 PIC X(32) VALUE "34ﾋﾛｼﾏｹﾝ 広島県 ".
05 PIC X(32) VALUE "35ﾔﾏｸﾞﾁｹﾝ 山口県 ".
05 PIC X(32) VALUE "36ﾄｸｼﾏｹﾝ 徳島県 ".
05 PIC X(32) VALUE "37ｶｶﾞﾜｹﾝ 香川県 ".
05 PIC X(32) VALUE "38ｴﾋﾒｹﾝ 愛媛県 ".
05 PIC X(32) VALUE "39ｺｳﾁｹﾝ 高知県 ".
05 PIC X(32) VALUE "40ﾌｸｵｶｹﾝ 福岡県 ".
05 PIC X(32) VALUE "41ｻｶﾞｹﾝ 佐賀県 ".
05 PIC X(32) VALUE "42ﾅｶﾞｻｷｹﾝ 長崎県 ".
05 PIC X(32) VALUE "43ｸﾏﾓﾄｹﾝ 熊本県 ".
05 PIC X(32) VALUE "44ｵｵｲﾀｹﾝ 大分県 ".
05 PIC X(32) VALUE "45ﾐﾔｻﾞｷｹﾝ 宮崎県 ".
05 PIC X(32) VALUE "46ｶｺﾞｼﾏｹﾝ 鹿児島県 ".
05 PIC X(32) VALUE "47ｵｷﾅﾜｹﾝ 沖縄県 ".
03 PRFCTTBL-R REDEFINES PRFCTTBL-VALUE.
05 PRFCT-REC OCCURS 47.
07 PREFECTCD PIC X(02).
07 PREFECTNAMEKANA PIC X(10).
07 PREFECTNAMEKANJI PIC N(10).
コンパイルする
実行するコマンドはcobc -m GETPRFCT.COB -I /home/各ユーザID/copy
(-I以降はコピー句を使用する場合のコピーライブラリを指定)
サブプロを実行するドライバプログラムを作成する
ソースの作成場所と名前は以下の通り。→C:/cygwin/home/各ユーザID/cobol/DRV00001.COB
IDENTIFICATION DIVISION.
PROGRAM-ID. DRV00001.
AUTHOR. JIRO SUZUKI.
*------------------------------------------------------------
* 県名取得確認用ドライバー
*------------------------------------------------------------
DATA DIVISION.
WORKING-STORAGE SECTION.
01 WORK-AREA.
03 W-PREFECTCD PIC X(02).
03 W-PREFECTCD-R REDEFINES W-PREFECTCD PIC 9(02).
03 IDX PIC 9(02) COMP-3.
COPY IO-PREFECT. *>ここにｲﾝﾀｰﾌｪｰｽのｺﾋﾟｰ句を指定
PROCEDURE DIVISION.
MAIN SECTION.
DISPLAY "----- ｹﾝﾒｲ ｼｭﾄｸ(PGM=GETPRFCT) TEST START -----".
*
INITIALIZE IO-PREFECT. *>ｲﾝﾀｰﾌｪｰｽ初期化
MOVE SPACE TO IO-PREFECT.
*
MOVE 1 TO IDX.
PERFORM UNTIL IDX >47
MOVE IDX TO W-PREFECTCD-R
MOVE W-PREFECTCD TO PREFECTCD OF IO-PREFECT
CALL "GETPRFCT" USING IO-PREFECT
DISPLAY "--- ﾉｰﾏﾙ ｹｰｽ ---"
DISPLAY "PRFCTCD=" PREFECTCD OF IO-PREFECT
DISPLAY "RTNCD =" RTNCD OF IO-PREFECT
DISPLAY "PREFECTNAMEKANA =" PREFECTNAMEKANA OF IO-PREFECT
DISPLAY "PREFECTNAMEKANJI=" PREFECTNAMEKANJI OF IO-PREFECT
ADD 1 TO IDX
END-PERFORM.
*
INITIALIZE IO-PREFECT.
MOVE SPACE TO IO-PREFECT.
MOVE SPACE TO PREFECTCD OF IO-PREFECT.
CALL "GETPRFCT" USING IO-PREFECT.
DISPLAY "--- ﾆｭｳﾘｮｸｴﾗｰ ｹｰｽ ---".
DISPLAY "PRFCTCD=" PREFECTCD OF IO-PREFECT.
DISPLAY "RTNCD =" RTNCD OF IO-PREFECT.
DISPLAY "PREFECTNAMEKANA =" PREFECTNAMEKANA OF IO-PREFECT.
DISPLAY "PREFECTNAMEKANJI=" PREFECTNAMEKANJI OF IO-PREFECT.
*
INITIALIZE IO-PREFECT.
MOVE SPACE TO IO-PREFECT.
MOVE "00" TO PREFECTCD OF IO-PREFECT.
CALL "GETPRFCT" USING IO-PREFECT.
DISPLAY "--- ｱﾝﾏｯﾁ ｹｰｽ ---".
DISPLAY "PRFCTCD=" PREFECTCD OF IO-PREFECT.
DISPLAY "RTNCD =" RTNCD OF IO-PREFECT.
DISPLAY "PREFECTNAMEKANA =" PREFECTNAMEKANA OF IO-PREFECT.
DISPLAY "PREFECTNAMEKANJI=" PREFECTNAMEKANJI OF IO-PREFECT.
*
DISPLAY "----- ｹﾝﾒｲ ｼｭﾄｸ(PGM=GETPRFCT) TEST END -----".
STOP RUN.
ドライバプログラムをコンパイルする
実行するコマンドはcobc -x DRV00001.COB -I /home/各ユーザID/copy
ドライバプログラムを実行する
実行するコマンドは./DRV00001
結果を確認する
DISPLAYした内容がCygwinの画面に表示される。